Creek&River Co., Ltd.

この度は、美しい花火、アイディア満載の花火、衝撃的な花火など、いろいろな花火のご投稿ありがとうございました！またそれぞれの作品にforkしてくださった方、コメントしてくださった方もありがとうございます！
forkすることによって、より動きのある作品に変化していく姿も楽しんで見ていました。
1ヶ月で終えるのはとても名残惜しいですが、これからもwondelfulで新しいクリエイティブを生み出し、Action scriptの可能性が広がることを楽しみにしています！

First of all, thank you for submitting many firework works such as beautiful fireworks, full idea of fireworks, crashing fireworks and so on. Also, we appriciate those who forked or left comments!
We enjoyed watching each works's shape that keeps changing by forking.
Although, it is regretful to end this challenge, we are looking forward to the new creation produced by wonderfl from now on, and the widespread of ability of ActionScript!

  1. Queen
    coppieee
    present 書籍『Flash + After Effects』と魚沼産コシヒカリ （書籍提供：ボーンデジタル）
    "Flash + After Effects"(a book written by Chris Jackson, 2009, presented by Born Digital, Inc.) and Koshihikari, Japanese top brand rice.
  2. Bishop
    sekiryou
    present「PUSH」映画鑑賞チケット＆DVD「椿姫彩菜ビューティートライアルフィットネスタイチー」とC&R社グッズ（チケット・DVD提供：株式会社プレシディオ）
    Ticket for movie "PUSH," DVD"Ayana Tsubaki's beauty trial fitness 'TaiChi'," and CREEK & RIVER's goods.(Ticket and DVD are presented by PRESIDIO CORPORATION)
  3. Knight
    yd_niku
    presentgolla：Mac13インチバッグ『Black Deal 13』＆i-phoneケース『Black SLIMCASE(L) TURQUOISE』　（提供：golla）
    golla, Laptop sleeve "Black Deal 13" for Mac13 and iPhone case "Black SLIMCASE(L) TURQUOISE" (presented by golla)

View All Other Challengers

Queencoppieee

  1. /**
  2.  * たーまやー。
  3.  * 正規表現に苦戦しながらも、twitterでヘルプを求めて出来上がった作品。
  4.  * Twitterで打ち上げたいコメントを、
  5.  * #hanabi [（ ﾟдﾟ ）]
  6.  * のように #hanabi [コメント]って書けば打ち上げリストに追加されるよ！
  7.  * []は必須だからちゃんと付けてね！
  8.  * 
  9.  * Tweet hanabi!のボタンを押せばテンプレが表示される。
  10.  * 
  11.  * 花火リスト
  12.  * http://search.twitter.com/search?q=%23hanabi
  13.  * 
  14.  * katan_t irgal_ Horiuchi_H katan_t repeatedly aibou nakawake seisuke uwitenpen beinteractive 
  15.  * に感謝！
  16.  * @author coppieee
  17.  */
  18. package {
  19.     import com.bit101.components.PushButton;
  20.     import flash.display.*;
  21.     import flash.events.*;
  22.     import flash.geom.*;
  23.     import flash.net.*;
  24.     import flash.text.engine.TextBlock;
  25.     import flash.text.engine.TextElement;
  26.     import flash.text.engine.TextLine;
  27.     import flash.text.TextField;
  28.     import flash.text.TextFieldAutoSize;
  29.     import flash.text.TextFormat;
  30.     import flash.utils.*;
  31.     import flash.system.*;
  32.     import com.flashdynamix.utils.*;
  34.     [SWF(backgroundColor=0x000000, frameRate=60)]
  35.     public class Sponsor extends Sprite {
  36.      
  37.         private var _particles:Vector.<Object>;
  38.         private var _gradientMap:BitmapData; 
  39.         private var _timer:Timer; 
  40.    
  41.         private static const PARTICLES_LENGTH:int = 1000;
  42.         //private static const _texts:Array = ["（ ﾟдﾟ ）","＼(＾o＾)／","(｢・ω・)｢",""];
  43.         private var _texts:Array;
  44.         private var _newestTexts:Array;
  45.         private function setup():void {
  46.             //Wonderfl.capture_delay(2);
  47.             _gradientMap= new BitmapData(200,10, true, 0);
  48.              //addChild( new Bitmap( _gradientMap) ); // for debug
  49.             updateGradientFill();
  50.                 
  51.             //shotFirework();
  52.             shotAA();
  53.            
  54.             _timer = new Timer( 5000, 0 );
  55.             _timer.addEventListener( TimerEvent.TIMER, timerHadler );
  56.             _timer.start();
  57.             
  58.             _loader = new Loader();
  59.             _loader.contentLoaderInfo.addEventListener( Event.COMPLETE, onLoadComplete );
  60.             _loader.load( new URLRequest("http://level0.kayac.com/space.jpg"), new LoaderContext(true) );
  61.             
  62.             
  63.             //var textLoader:URLLoader =  new URLLoader(new URLRequest("http://search.twitter.com/search.atom?q=%23hanabi&rpp=100"));
  64.             //textLoader.addEventListener(Event.COMPLETE, function(e:Event):void {
  65.                 //default xml namespace = new Namespace("http://www.w3.org/2005/Atom");
  66.                 //var htmlText:XML = XML(textLoader.data);
  67.                 //var title:XMLList = htmlText.entry.title;
  68.                 //var xs:Array = [];
  69.                 //for each(var c:XML in  title)
  70.                 //{
  71.                     //xs.push.apply(null,scan(c.toString(),/\[(.+)\]/));
  72.                 //}
  73.                 //if (xs.length >= 1)
  74.                 //{
  75.                     //_texts = xs;
  76.                 //}
  77.             //});
  78.             var loadTexts:Function = function (rpp:int, arraySetter:Function):void {
  79.                 var textLoader:URLLoader = new URLLoader(new URLRequest("http://search.twitter.com/search.atom?q=%23hanabi&rpp=" + rpp));
  80.                 textLoader.addEventListener(Event.COMPLETE, function(e:Event):void {
  81.                     default xml namespace = new Namespace("http://www.w3.org/2005/Atom");
  82.                     var htmlText:XML = XML(textLoader.data);
  83.                     var title:XMLList = htmlText.entry.title;
  84.                     var xs:Array = [];
  85.                     for each(var c:XML in  title)
  86.                     {
  87.                         xs.push.apply(null,scan(c.toString(),/\[(.+)\]/));
  88.                     }
  89.                     if (xs.length >= 1)
  90.                     {
  91.                         //_texts = xs;
  92.                         arraySetter(xs);
  93.                     }
  94.                 });
  95.             }
  96.             loadTexts(100, function(arr:Array):void { _texts = arr } );
  97.             loadTexts(20, function(arr:Array):void { _newestTexts = arr } );
  98.             
  99.             var tweetButton:PushButton = new PushButton(this);
  100.             tweetButton.label = "Tweet Hanabi!";
  101.             tweetButton.alpha = 0.8;
  102.             tweetButton.x = (465 - tweetButton.width) / 2;
  103.             tweetButton.y = (465 - tweetButton.height);
  104.             tweetButton.addEventListener(MouseEvent.CLICK, function(e:MouseEvent):void {
  105.                 navigateToURL(new URLRequest("http://twitter.com/home/?status=" 
  106.                     + escapeMultiByte("#hanabi [] http://bit.ly/AAHanabi")
  107.                 ));
  108.             });
  109.             
  110.         }
  111.         private var _loader:Loader;
  112.         private function onLoadComplete(e:Event):void {
  113.             addChildAt( _loader.content, 0 ); 
  114.         }
  115.         
  116.         private function shotAA():void
  117.         {
  118.             var text:String = "(・ω・)";
  119.             
  120.             if (_texts != null && _newestTexts != null)
  121.             {
  122.                 if (Math.random() > 0.5)
  123.                 {
  124.                     text = _texts[Math.floor(_texts.length * Math.random())];
  125.                 }else
  126.                 {
  127.                     text = _newestTexts[Math.floor(_newestTexts.length * Math.random())];
  128.                 }
  129.             }
  130.             _particles = new Vector.<Object>();
  131.             
  132.             var tf:TextField = new TextField();
  133.             tf.autoSize = TextFieldAutoSize.LEFT;
  134.             var format:TextFormat = new TextFormat();
  135.             format.size = 20;
  136.             tf.defaultTextFormat = format;
  137.             tf.text = text;
  138.             var b:BitmapData = new BitmapData(tf.width, tf.height, false);
  139.             b.draw(tf);
  140.             const offsetX:int = 0;
  141.             const offsetY:int = - 45;
  142.             const scale:Number = 20/b.width;
  143.             for (var i:int = 0; i < b.width; i++ )
  144.             {
  145.                 for (var j:int = 0; j < b.height; j++ )
  146.                 {
  147.                     if (b.getPixel(i, j) == 0xFFFFFF) { continue ; }
  148.                     
  149.                     var direction:Number = Math.random()*Math.PI*2;
  150.                     var tx:Number = Math.sin(direction);
  151.                     var ty:Number = Math.cos(direction);
  152.                     //var sl:Number = Math.random()* radius +2;
  153.                     var vl:Number = Math.random()/10;
  154.                     
  155.                     var p:Object = {
  156.                         x:_center.x,
  157.                         y:_center.y,
  158.                         vx:(i -b.width / 2) *scale + tx*vl,
  159.                         vy:(j -b.height / 2) *scale +ty*vl,
  160.                         life:Math.random()*30+170
  161.                     };
  162.                     _particles.push(p);
  163.                     
  164.                 }
  165.             }
  166.             b.dispose();
  167.             
  168.         }
  169.         
  170.         private static const FRICTION:Number = 0.96;
  171.         private static const GRAVITY:Number = 0.006;
  172.         private static const WIND:Point = new Point(0.001,0 );
  173.         
  174.         private function updateCalcuration():void{
  175.             for each( var p:Object in _particles ) {
  176.                 p.vx =  p.vx * FRICTION + WIND.x + Math.random()*0.01-.005;
  177.                 p.vy =  p.vy * FRICTION + WIND.y + GRAVITY + Math.random()*0.01-.005;
  178.                 p.x = p.x + p.vx;
  179.                 p.y = p.y + p.vy;
  180.                 p.life--;
  181.             }
  182.         }
  183.         
  184.         private function updateDrawing():void{
  185.             _canvas.colorTransform( _canvas.rect, CTF );
  186.             _canvas.lock();
  187.             for each( var p:Object in _particles ) {
  188.                 if( p.life <= 0 ) continue;
  189.                 _canvas.setPixel32( p.x, p.y, getColor(p.life) );
  190.             }
  191.             _canvas.unlock();
  192.         }
  193.          
  194.         private function timerHadler (e:Event):void{
  195.            updateGradientFill();
  196.             _particles = null;
  197.             //shotFirework();
  198.             shotAA();
  199.         }
  200.          
  201.         private function getColor(position:int):uint {
  202.             return _gradientMap.getPixel( position, 0 ) | 0xFF000000;
  203.         }
  204.         
  205.         private const CTF:ColorTransform = new ColorTransform( 0.94, 0.94, 0.94, 0.9 );
  206.         private const COLORS:Array = [ 0xFFCCFF, 0xFF9999, 0xFFFF99, 0x99CCFF, 0xCCFF99 ];
  207.         private function updateGradientFill():void {
  208.             var sp:Shape= new Shape();
  209.             var color:uint = COLORS[ Math.random()*COLORS.length>>0];
  210.             var mtx:Matrix = new Matrix();
  211.             mtx.createGradientBox(200, 0, 0, 0, 0);
  212.             sp.graphics.beginGradientFill( GradientType.LINEAR,
  213.                 [ 0x333333, color, color, color*0.9>>0, 0x000000 ],
  214.                 [ 1, 1, 1, 1, 1 ],
  215.                 [ 8, 64, 102, 204, 255],
  216.                 mtx,
  217.                 InterpolationMethod.RGB
  218.             );
  219.             sp.graphics.drawRect( 0, 0, 200, 10 );
  220.             sp.graphics.endFill();
  221.             _gradientMap.draw(sp);
  222.             sp = null;    
  223.         }
  224.         
  225.         private var _canvas:BitmapData;
  226.         private var _center:Point;
  227.         private function init():void{
  228.             _center= new Point();
  229.             _center.x = stage.stageWidth*0.5>>0;
  230.             _center.y = stage.stageHeight*0.5>>0;
  231.             
  232.             _canvas  = new BitmapData( stage.stageWidth, stage.stageHeight, true, 0 );
  233.             addChild( new Bitmap(_canvas) );
  234.             
  235.             setup();
  236.             addEventListener( Event.ENTER_FRAME, enterFrame);
  237.             
  238.             SWFProfiler.init( this );
  239.         }
  240.         private function enterFrame( e:Event ):void {
  241.             updateCalcuration();
  242.             updateDrawing();
  243.         }
  244.         
  245.         public function Sponsor() {
  246.             addEventListener( Event.ADDED_TO_STAGE, addToStage );
  247.         }
  248.         private function addToStage (e:Event):void {
  249.             init();
  250.         }
  251.     }
  252. }
  253. /**
  254.  * @see http://takumakei.blogspot.com/2009/05/actionscriptrubystringscan.html
  255.  */ 
  256. //package com.blogspot.takumakei.utils
  257. //{
  258.     //public
  259.     function scan(str:String, re:RegExp):Array
  260.     {
  261.         if(!re.global){
  262.             var flags:String = 'g';
  263.             
  264.             if(re.dotall)
  265.                 flags += 's';
  266.             if(re.multiline)
  267.                 flags += 'm';
  268.             if(re.ignoreCase)
  269.                 flags += 'i';
  270.             if(re.extended)
  271.                 flags += 'x';
  273.             re = new RegExp(re.source, flags);                    
  274.         }
  276.         var r:Array = [];
  277.         var m:Array = re.exec(str);
  278.         while(null != m){
  279.             if(1 == m.length)
  280.                 r.push(m[0]);
  281.             else
  282.                 r.push(m.slice(1, m.length));
  283.             m = re.exec(str);
  284.         }
  285.         return r;
  286.     }
  287. //}
  288.     
noswf download
flash swf thumbnail play
出題者からのコメント
twitterと花火の連携アイディアに脱帽！すごく面白いです。
twitterでつぶやいたコメントが花火になるなんて～♪♪
花火が消え行く様もとても儚くてGOOD。弊社も早速、ログインして打ち上げてみました！
Comments from Sponsor
Cooperated idea of fireworks with twitter is so interesting!
After tweeting in twitter, the comment becomes fireworks! ♪♪
It's good that fireworks is disappeared momentarily. We have enjoyed tweeting.

Bishopsekiryou

  1. // forked from checkmate's Creek challenge
  2. package {
  3.     import flash.display.MovieClip;
  4.     import flash.events.Event;
  5.     import flash.display.Bitmap;
  6.     import flash.display.BitmapData;
  7.     import flash.geom.Matrix;
  8.     import flash.geom.Point;
  9.     import flash.display.BlendMode;
  10.     import flash.display.PixelSnapping;
  11.     import flash.geom.Rectangle;
  12.     import flash.geom.ColorTransform;
  13.     import flash.filters.BlurFilter;
  15.     [SWF(width = "465", height = "465", backgroundColor = "0x000000", frameRate = "30")]
  17.     public class BeneathSpark extends MovieClip {
  18.         private var _canvas:BitmapData;
  19.         private var bmp:Bitmap;
  20.         private var _particles:Array;
  21.         private var _glow:BitmapData;
  22.         private var _rect:Rectangle;
  23.         private var cTra:ColorTransform;
  25.         private var FocalLength:Number = 200;
  26.         private var bullets:Array = [];
  27.         private const bulletAmount:uint = 20;
  28.         private var particles:Array = [];
  30.         private const STAGE_WIDTH = stage.stageWidth;
  31.         private const STAGE_HEIGHT = stage.stageHeight;
  32.         private const STAGE_CENTER_X = stage.stageWidth / 2;
  33.         private const STAGE_CENTER_Y = stage.stageHeight / 2;
  35.         public function BeneathSpark()
  36.         {
  37.             init()
  38.         }
  39.         private function init():void
  40.         {
  41.             _particles = [];
  42.             _canvas = new BitmapData (STAGE_WIDTH, STAGE_HEIGHT, true, 0xFFFFFF);
  43.             bmp = new Bitmap (_canvas);
  44.             addChild (bmp);
  46.             _glow = new BitmapData( STAGE_WIDTH/4, STAGE_HEIGHT/4, false, 0x0);
  47.             var bm:Bitmap = addChild(new Bitmap(_glow, PixelSnapping.NEVER, true)) as Bitmap;
  48.             bm.scaleX = bm.scaleY = 4;
  49.             bm.blendMode = BlendMode.ADD;
  51.             _rect = new Rectangle(0, 0, STAGE_WIDTH, STAGE_HEIGHT);
  52.             cTra = new ColorTransform( 0.95, 0.95, 0.95, 1.2 );
  54.             for ( var i = 0; i < bulletAmount; i++ )
  55.             {
  56.                 var p:bullet = new bullet();
  57.                 bullets.push( p );
  58.                 purposePoint( p );
  60.                 p.PositionY -= 280;
  61.             }
  63.             addEventListener(Event.ENTER_FRAME, onEventHandler);
  64.         }
  65.         private function createParticle( sx:Number, sy:Number, sz:Number ):void
  66.         {
  67.             var i:int = 120;
  68.             while (i--) {
  69.                 var p:Particle = new Particle();
  70.                 p.PositionX = sx;
  71.                 p.PositionY = sy;
  72.                 p.PositionZ = sz;
  74.                 var radius:Number = Math.sqrt(Math.random()) * 1.3;
  75.                 var angle:Number = Math.random() * Math.PI * 2;
  76.                 var angle2:Number = Math.random() * Math.PI * 2;
  78.                 p.vx = Math.cos( angle ) * radius;
  79.                 p.vy = Math.sin( angle2 ) * radius;
  80.                 p.vz = Math.sin( angle ) * radius;
  82.                 _particles.push(p);
  83.             }
  84.         }
  85.         private function purposePoint( t )
  86.         {
  87.             t.PurposeX = Math.random() * 120 -60;
  88.             t.PurposeY = Math.random() * 40 -160
  89.             t.PurposeZ = Math.random() * 120 -60;
  91.             var rnd:Number = ( Math.random() * 2 + 2 ) / 400;
  92.             t.vx = ( t.PurposeX - t.PositionX ) * rnd;
  93.             t.vy = ( t.PurposeY - t.PositionY ) * rnd;
  94.             t.vz = ( t.PurposeZ - t.PositionZ ) * rnd;
  95.         }
  96.         private function WtoS( t ):void
  97.         {
  98.             if ( t.PositionY > -FocalLength ) {
  99.                 t.scale = FocalLength / (FocalLength + t.PositionY);
  100.                 t.px = STAGE_CENTER_X + t.PositionX * t.scale;
  101.                 t.py = STAGE_CENTER_Y + t.PositionZ * t.scale;
  102.                 t.visible = true;
  103.             } else {
  104.                 t.visible = false;
  105.             }
  106.         }
  108.         private var cRot:Number = 0;
  109.         private function onEventHandler(eventObject:Event):void
  110.         {
  111.             var variation:Number = 0.04;
  112.             var ctx =  mouseX / 465;
  113.             var cty = mouseY / 465;
  114.             if ( ctx > 0.95 ) {
  115.                 ctx = 0.95;
  116.             } else if ( ctx < 0.05 ) {
  117.                 ctx = 0.05;
  118.             }
  119.             if ( cty > 0.95 ) {
  120.                 cty = 0.95;
  121.             } else if ( cty < 0.05 ) {
  122.                 cty = 0.05;
  123.             }
  124.             if ( ctx > cTra.redMultiplier ) {
  125.                 cTra.redMultiplier += variation;
  126.             } else {
  127.                 cTra.redMultiplier -= variation;
  128.             }
  129.             if ( cty > cTra.greenMultiplier ) {
  130.                 cTra.greenMultiplier += variation;
  131.             } else {
  132.                 cTra.greenMultiplier -= variation;
  133.             }
  135.             cTra.blueMultiplier = ( Math.sin(cRot) + 1 ) / 2 * 0.95;
  136.             cRot += 0.01;
  138.             var i:uint = bullets.length;
  139.             while (i--) {
  140.                 if ( bullets[ i ].PositionY < bullets[ i ].PurposeY ) {
  141.                     createParticle( bullets[ i ].PurposeX, bullets[ i ].PurposeY, bullets[ i ].PurposeZ );
  142.                     bullets[ i ].launchPoint();
  143.                     purposePoint( bullets[ i ] );
  144.                 } else {
  145.                     bullets[ i ].PositionX += bullets[ i ].vx;
  146.                     bullets[ i ].PositionY += bullets[ i ].vy;
  147.                     bullets[ i ].PositionZ += bullets[ i ].vz;
  148.                 }
  149.             }
  151.             _canvas.lock();
  152.             _canvas.applyFilter( _canvas, _rect, new Point(), new BlurFilter( 2.4, 2.4 ) );
  153.             _canvas.colorTransform(_rect, cTra);
  155.             i = _particles.length;
  156.             while (i--) {
  157.                 var p:Particle = _particles[i];
  158.                 p.vy -= 0.06;
  160.                 p.vx *= 0.9;
  161.                 p.vy *= 0.9;
  162.                 p.vz *= 0.9;
  164.                 p.PositionX += p.vx;
  165.                 p.PositionY += p.vy;
  166.                 p.PositionZ += p.vz;
  168.                 WtoS( p );
  169.                 p.x = p.px;
  170.                 p.y = p.py;
  172.                 _canvas.setPixel32(p.x, p.y, p.c);
  173.                 if ( (p.x > stage.stageWidth || p.x < 0) || (p.y < 0 || p.y > stage.stageHeight) || Math.abs(p.vy) < -1.0 )
  174.                 {
  175.                     this._particles.splice(i, 1);
  176.                 }
  177.             }
  178.             _canvas.unlock();
  179.             _glow.draw(_canvas, new Matrix(0.25, 0, 0, 0.25));
  180.         }
  181.     }
  182. }
  184. import flash.display.Sprite;
  185. class bullet extends Sprite
  186. {
  187.     public var scale:Number;
  189.     public var PositionX:Number;
  190.     public var PositionY:Number;
  191.     public var PositionZ:Number;
  192.     public var PurposeX:Number;
  193.     public var PurposeY:Number;
  194.     public var PurposeZ:Number;
  196.     public var px:Number;
  197.     public var py:Number;
  198.     public var pz:Number;
  199.     public var vx:Number;
  200.     public var vy:Number;
  201.     public var vz:Number;
  203.     public function bullet()
  204.     {
  205.         launchPoint();
  206.     }
  207.     public function launchPoint():void {
  208.         PositionX =  0;
  209.         PositionY = 250
  210.         PositionZ = 200;
  211.     }
  212. }
  214. class Particle
  215. {
  216.     public var x:Number;
  217.     public var y:Number;
  218.     public var visible:Boolean;
  219.     public var scale:Number;
  221.     public var PositionX:Number;
  222.     public var PositionY:Number;
  223.     public var PositionZ:Number;
  225.     public var px:Number;
  226.     public var py:Number;
  227.     public var pz:Number;
  228.     public var vx:Number;
  229.     public var vy:Number;
  230.     public var vz:Number;
  231.     public var c:uint;
  233.     public function Particle()
  234.     {
  235.         this.x = 0;
  236.         this.y = 0;
  237.         this.vx = 0;
  238.         this.vy = 0;
  239.         this.vz = 0;
  240.         this.c = 0xffffffff;
  241.     }
  242. }
noswf download
flash swf thumbnail play
出題者からのコメント
花火を真下から見る構図に斬新さを感じました。
また、夜空に打ちあがる花火でなく、「宇宙（そら）にある星（流星群）」のようにも見えて、弊社のお題と素敵にリンク☆ありがとうございました！
Comments from Sponsor
This is the new idea that fireworks will be seen from the bottom.
Not only driving fireworks in the sky at night, but also it looks like "meteoric swarm in the universe," that has close ties to this theme. Thank you very much!

Knightyd_niku

  1. // forked from checkmate's Creek challenge
  2. //途中
  3. package {
  4.     import flash.display.*;
  5.     import flash.events.*;
  6.     import flash.geom.*;
  7.     import flash.net.*;
  8.     import flash.utils.*;
  9.     import flash.system.*;
  10.     import com.flashdynamix.utils.*;
  11.     
  12.     [SWF(backgroundColor=0x000000, frameRate=60)]
  13.     public class Sponsor extends Sprite {
  14.         
  15.         private var _gradientMap:BitmapData; 
  16.         private var _timer:Timer;
  17.         private var _camera:Camera3D;
  18.         
  19.         private function setup():void{
  20.             _timer = new Timer( 800, 0 );
  21.             _timer.addEventListener( TimerEvent.TIMER, timerHadler );
  22.             _timer.start();
  23.             
  24.             _camera = new Camera3D();
  25.             
  26.             shotFirework();
  27.             
  28.             _loader = new Loader();
  29.             _loader.contentLoaderInfo.addEventListener( Event.COMPLETE, onLoadComplete );
  30.             _loader.load( new URLRequest("http://level0.kayac.com/space.jpg"), new LoaderContext(true) );
  31.         } 
  32.         private var _loader:Loader;
  33.         private var _background:DisplayObject;
  34.         private function onLoadComplete(e:Event):void {
  35.             _background = addChildAt( _loader.content, 0 ); 
  36.         }
  37.         
  38.         
  39.         private var _fireworks:Vector.<Firework> = new Vector.<Firework>();
  40.         private function shotFirework():void {
  41.             var fw:Firework =new Firework();
  42.             fw.shot( Math.random()*5 + 1 );
  43.             fw.x = Math.random() * 300 -150;
  44.             fw.y = -Math.random() * 100 -50;
  45.             fw.z = Math.random() * 300  -150;
  46.             _fireworks.push( fw );
  47.         }
  48.         
  49.         
  50.         private var _velocityWorldRot:Vector3D = new Vector3D();
  51.         private var _preMouse:Point = new Point();
  52.         private function updateCalcuration():void{
  53.             _velocityWorldRot.x += ( _preMouse.x - mouseX ) * 0.02;
  54.             _velocityWorldRot.x *= 0.90;
  55.             _velocityWorldRot.y += ( _preMouse.y- mouseY ) * 0.02;
  56.             _velocityWorldRot.y *= 0.90;
  57.             _preMouse.x = mouseX;
  58.             _preMouse.y = mouseY;
  59.             
  60.             _world.appendRotation( _velocityWorldRot.x, Vector3D.Y_AXIS );
  61.             _world.appendRotation( _velocityWorldRot.y, Vector3D.X_AXIS );
  62.             
  63.             for each( var fw:Firework in _fireworks ) fw.updateCalcuration();
  64.         }
  65.         
  66.         private var _world:Matrix3D = new Matrix3D();
  67.         private function updateDrawing():void{
  68.             //_background.rotationX = 
  69.             
  70.             _canvas.colorTransform( _canvas.rect, CTF );
  71.             _canvas.lock();
  72.             for each( var fw:Firework in _fireworks ) {
  73.                 fw.draw( _canvas, _world, _camera );
  74.             }
  75.             _canvas.unlock();
  76.         }
  77.         
  78.         private function timerHadler (e:Event):void{
  79.             var newFireworks:Vector.<Firework>= new Vector.<Firework>();
  80.             for each( var fw:Firework in _fireworks ) {
  81.                 fw.cleanup();
  82.                 if( fw.isLiving )  newFireworks.push(fw);
  83.             }
  84.             _fireworks = newFireworks;
  85.             shotFirework();
  86.         }
  87.         
  88.         private const CTF:ColorTransform = new ColorTransform( 0.94, 0.94, 0.94, 0.9 );
  89.         private var _canvas:BitmapData;
  90.         
  91.         private function init():void{
  92.             Firework.offset.x = stage.stageWidth*0.5>>0;
  93.             Firework.offset.y = stage.stageHeight*0.5>>0;
  94.             
  95.             _canvas  = new BitmapData( stage.stageWidth, stage.stageHeight, true, 0 );
  96.             addChild( new Bitmap(_canvas) );
  97.             
  98.             setup();
  99.             addEventListener( Event.ENTER_FRAME, enterFrame);
  100.             
  101.             SWFProfiler.init( this );
  102.         }
  103.         private function enterFrame( e:Event ):void {
  104.             updateCalcuration();
  105.             updateDrawing();
  106.         }
  107.         
  108.         
  109.         
  110.         
  111.         public function Sponsor() {
  112.             addEventListener( Event.ADDED_TO_STAGE, addToStage );
  113.         }
  114.         private function addToStage (e:Event):void {
  115.             init();
  116.         }
  117.     }
  118. }
  120. import flash.display.*;
  121. import flash.events.*;
  122. import flash.geom.*;
  123. import flash.net.*;
  124. import flash.utils.*;
  125. import flash.system.*;
  128. class Particle extends Vector3D {
  129.     public var life:int;
  130.     public var vx:Number;
  131.     public var vy:Number;
  132.     public var vz:Number;
  133.         public var rmd:Number = Math.random()*0.005-0.0025;
  134.     public function Particle( x:Number = 0, y:Number = 0, z:Number = 0, vx:Number = 0, vy:Number = 0, vz:Number = 0, life:int = 200 ) {
  135.         super( x, y, z );
  136.         this.vx = vx;
  137.         this.vy = vy;
  138.         this.vz = vz;
  139.         this.life = life;
  140.     }
  141. }
  143. class Camera3D extends Vector3D {
  144.     public var focus:int = 1000;
  145.     public function Camera3D( x:Number = 0, y:Number = 0, z:Number = 0 ) {
  146.         super( x, y, z );
  147.     }
  148. }
  150. class Firework extends Vector3D {
  151.     private static const PARTICLES_LENGTH:int = 600;
  152.     private static const COLORS:Array = [ 0xFFCCFF, 0xFF9999, 0xFFFF99, 0x99CCFF, 0xCCFF99 ];
  153.     
  154.     private static const FRICTION:Vector3D = new Vector3D ( 0.94, 0.94, 0.94 );
  155.     private static const GRAVITY:Vector3D = new Vector3D ( 0, 0.008, 0 );
  156.     private static const WIND:Vector3D = new Vector3D ( 0.001, 0,0 );
  157.     
  158.     public static var offset:Point = new Point();
  159.     
  160.     private var _particles:Vector.<Particle> = new Vector.<Particle>();
  161.     private var _gradientMap:BitmapData;
  162.         
  163.     public function Firework() {
  164.         updateGradiate();
  165.     }
  166.     
  167.     public function draw( canvas:BitmapData,  world:Matrix3D, camera:Camera3D ):void {
  168.         for each( var p:Particle in _particles ) {
  169.             if ( p.life <= 0 ) continue;
  170.             
  171.             var projected:Vector3D = Utils3D.projectVector( world, p .add( this ) );
  172.             
  173.             var persepective:Number = camera.focus / ( camera.focus + projected.z );
  174.             var px:Number = projected.x * persepective + offset.x;
  175.             var py:Number = projected.y * persepective + offset.y;
  176.             var a:uint = ( 255 * 5 / persepective ) << 24;
  177.             canvas.setPixel32( px, py, getColor(p.life) | a );
  178.         }    
  179.     }
  180.     
  181.     private function updateGradiate():void {
  182.         _gradientMap= new BitmapData(200,10, true, 0);
  183.         var sp:Shape= new Shape();
  184.         var color:uint = COLORS[ Math.random()*COLORS.length>>0];
  185.         var mtx:Matrix = new Matrix();
  186.         mtx.createGradientBox(200, 0, 0, 0, 0);
  187.         sp.graphics.beginGradientFill( GradientType.LINEAR,
  188.             [ 0x333333, color, color, color*0.9>>0, 0x000000 ],
  189.             [ 1, 1, 1, 1, 1 ],
  190.             [ 8, 64, 102, 204, 255],
  191.             mtx,
  192.             InterpolationMethod.RGB
  193.         );
  194.         sp.graphics.drawRect( 0, 0, 200, 10 );
  195.         sp.graphics.endFill();
  196.         _gradientMap.draw(sp);
  197.         sp = null;
  198.     }
  199.     
  200.     private function getColor(position:int):uint {
  201.         return _gradientMap.getPixel( position, 0 ) | 0x00000000;
  202.     }
  203.     
  204.     public function shot( radius:Number ):void {
  205.         var radian:Number = Math.PI*2;
  206.         
  207.         for( var i :int=0; i<PARTICLES_LENGTH; i++ ) {
  208.             var theta:Number = Math.random() *radian;
  209.             var phi:Number = Math.random() *radian;
  210.             var tx:Number = Math.sin(theta) * Math.sin(phi);
  211.             var ty:Number = Math.sin(theta) * Math.cos(phi);
  212.             var tz:Number = Math.cos(theta);
  213.             
  214.             var sl:Number = Math.random()*radius * 0.5;
  215.             var vl:Number = Math.random()*( 0.2 )*radius + 0.8 * radius;
  216.             
  217.             var particle :Particle= new Particle(
  218.                 tx*sl,
  219.                 ty*sl,
  220.                 tz*sl,
  221.                 tx*vl,
  222.                 ty*vl,
  223.                 tz*vl,
  224.                 100
  225.             );
  226.             _particles.push(particle);
  227.         }
  228.     }
  229.     public function get isLiving():Boolean {
  230.         return  _particles.length > 0;
  231.     }
  232.     public function updateCalcuration():void{
  233.         for each( var p:Particle in _particles ) {
  234.             p.vx =  p.vx * FRICTION.x + WIND.x + GRAVITY.x + p.rmd;
  235.             p.vy =  p.vy * FRICTION.y + WIND.y + GRAVITY.y + p.rmd;
  236.             p.vz =  p.vz * FRICTION.z + WIND.z + GRAVITY.z + p.rmd;
  237.             p.x = p.x + p.vx;
  238.             p.y = p.y + p.vy;
  239.             p.z = p.z + p.vz;
  240.             p.life--;
  241.         }
  242.         _particles = _particles.sort( _sort );
  243.     }
  244.     private function _sort(a:Vector3D, b:Vector3D):Number { 
  245.         return a.z > b.z ? -1 : a.z < b.z ? 1 : 0;
  246.     }
  247.     
  248.     public function cleanup():void {
  249.         var newParticles:Vector.<Particle> = new Vector.<Particle>();
  250.         for each( var p:Particle in _particles ) {
  251.             if( p.life > 0 ) newParticles.push(p);
  252.         }
  253.         _particles = newParticles;
  254.     }
  255. }
noswf download
flash swf thumbnail play
出題者からのコメント
カーソルの動きにあわせた3D花火というアイディアがよかっただけに、まだ「作成途中？」ということが残念。完成品を見たかった作品です。
Comments from Sponsor
The idea which combined the movement cursors to 3D fireworks was great, but what a pity, it's still "in the process of making"
This is the work that we wanted to see the complete one.

ad